how to make current color in Color Contro the same as the color of an object

[RChalmers2]

Is there a way to click on an object and have it's color be the current color in the Color Control dropdown?  Or some similar way to change the color control?

Thanks

[hgasty1001]

Hi,

You need a little help from Autolisp to do it:

(defun c:setcecolor (/ cecolor ent)
  (setq ent (car(entsel)))
  (if ent
    (if (setq cecolor (cdr (assoc 62 (entget ent))))
     (setvar "CECOLOR" (itoa cecolor))
     (alert "The selected entity has color set to Bylayer")
    )

 )
)

Gaston Nunez

[3wood · Accepted solution]

Something like this one?

(defun C:SetColorByObject (/ color colormethod bookname)
  ;;; SetColorByObject.lsp By 3wood (2014.11.12)
  (vl-load-com)
  (prompt "\nPick up an object to set current color:")
  (setq color (vla-get-truecolor (vlax-ename->vla-object(car(entsel))))
	colormethod (vla-get-colormethod color)
	bookname (vla-get-bookname color)
	)
  (cond
    ((= colormethod 192) (setvar "cecolor" "BYLAYER"))
    ((= colormethod 193) (setvar "cecolor" "BYBLOCK"))
    ((= colormethod 195) (setvar "cecolor" (itoa (vla-get-colorindex color))))
    ((and (= colormethod 194)(= bookname ""))
     (setvar "cecolor" (strcat "RGB:"
			       (itoa (vla-get-red color)) ","
			       (itoa (vla-get-green color)) ","
			       (itoa (vla-get-blue color))
			       )))
    ((= colormethod 194)(setvar "cecolor" (strcat bookname "$" (vla-get-colorname color))))
   )
  (princ)
)

[Kent1Cooper]

Here's a way that gets around the fact that there's no (assoc 62) entry in entity data for objects whose color is ByLayer:

(setvar 'cecolor (itoa (vla-get-color (vlax-ename->vla-object (car (entsel "\nSelect object to set its color current: "))))))

[It does require (vl-load-com) first if that hasn't already been done.]

[RChalmers2]

Works! Thanks.

[RChalmers2]

What is the command?

[RChalmers2]

I'm not a coder. Can you explain this?
Thanks

[RChalmers2]

I figured out the command. Works great! Thanks