Community
The attached Excel spreadsheet will calculate P2 and P4. The sample data I used was from the file EllipseApprox.
After calculating the coordinates for triangle P1, P3, P7 the task is to find P2 at the intersection of the angle bisectors at p1 and p7. Vector C is the angle bisector at p1, D the bisector at p7.
The general equation for the angle bisector can be expressed as:
C = |B| A + |A| B (bold font indicates a vector)
Using the parametric definition of a straight line: P = PA + t (PB-PA) for the angle bisector lines from P1 and P7 I calculated P2. In a similar fashion P4 is calculated.
Also, I could post my reviation when I have more time if you wish.
Lee
@Ry91, this has been a fun project. Thank you for the compliment.
The attached Excel file adds the location of the arc centers, c1, c2, c3, c4, and their radii. Just enter your data into the yellow cells and the output is in the green cells.
The calculation required the determination of two points on the perpendicular bisector between two points. Since this calculation was required several time I created a custom Excel function to compute the two points. The Excel file is therefore a Macro enable file (.xlsm).
perpbi(A,B) is an array function. It requires the x,y coordinates of two points (A and B) and outputs four values, the x,y coordinates of the mid-point and another point on the perpendicular bisector. Most Excel users are not familiar with array functions. To enter an array function you select a range of cells, enter the expression and then instead of hitting Enter, you hit Ctrl-Shift-Enter when you are done typing the expression. The braces {} indicate it is an array function. Do not type the {}, they are added when you hit CTrl-Shift-Enter. For example, the cells b35:c36 contain: {=perpbi(B4:C4,B23:C23)}. It takes the x and y coordinates found in B4:C4, and B23,C23 and calculates the x,y values for 2 points.
I created a second custom VBA function inters(A,B,C,D) to determine the intersection of two lines defined by two sets of two points.
Here's a listing of the two functions.
Function inters(A, B, C, D)
' 10/30/2018 L. Minardi
' an array function
'input = 4 points defining two lines. Each point is defined by two adjacent cells containing the
' the x and y coordinates of the point.
' Ax Ay
' Bx By
' Cx Cy
' Dx Dy
'output = a 2 element array containing the x,y coordinates of the
' point of intersection
' X Y x y coordinates of the intersection of line AB with line CD
Dim point(1 To 2) As Variant
ax = A(1)
ay = A(2)
bx = B(1)
by = B(2)
cx = C(1)
cy = C(2)
dx = D(1)
dy = D(2)
Top = (bx - ax) * (cy - ay) - (cx - ax) * (by - ay)
bot = (dx - cx) * (by - ay) - (dy - cy) * (bx - ax)
If bot <> 0 Then
u = Top / bot
point(1) = cx + u * (dx - cx)
point(2) = cy + u * (dy - cy)
Else
point(1) = "parallel"
point(2) = "lines"
End If
inters = point
End Function
Function perpbi(A, B)
' 10/30/2018 L. Minardi
'input = 2 points defining a line. Each point is defined by two adjacent cells containing the
' the x and y coordinates of the point.
' Ax Ay
' Bx By
' Output = a 2 row x 2 column array that contains the xy coordinates of:
' Cx Cy - a point at the midpoint between A and B
' Dx Dy - a point on the perpendicular bisector (but not C)
Dim points(1 To 2, 1 To 2) As Variant
ax = A(1)
ay = A(2)
bx = B(1)
by = B(2)
points(1, 1) = (ax + bx) / 2
points(1, 2) = (ay + by) / 2
points(2, 1) = points(1, 1) + ay - by
points(2, 2) = points(1, 2) - (ax - bx)
perpbi = points
End Function
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
