Angular Dimensions Showing " in Dimension

[Rellik28031]

I just started a new job where I am using AutoCAD 2010.  This is the newest version of AutoCAD I have ever used.  I am having a problem with angular dimensions.  When I get a angular dimension I have the inches mark showing up after the degree symbol.  This is slowing my production down cause I have to text edit the dimension to remove the inches mark.  Was curious if there was a fix to this problem.

Thank you

[Kent1Cooper]

Check the DIMPOST System Variable.  You may have an inch mark built in there -- set it back to the default empty string "".  For a particular Style, in the Dimension Style dialog box, look in the Primary Units tab for the presence of a Suffix.

[nestly2]

It sounds like someone added a suffix to a Dimstyle using Decimal units, but applied the suffix globally instead of creating Child Dimstyle for linear dimensions.  Removing the suffix, as Kent suggested with DIMPOST, will likely remove the inches mark from the angular dimensions and the linear dimension alike. 

Here's a quick video that may help understand what's going on, and how to correct it if you need the inches mark on Linear dimensions.  Hopefully you haven't overriden too many dimension texts, but even if you have, after setting up the dimstyle correctly, it's easy to remove the overrides.

http://www.screencast.com/t/DcIbkbkUmu

[steve216586]

We use the " suffix for inches here. Yes it can be cumbersome to have the degree symbol and also the " mark.

My solution has been to work as normal and ignore it, for the time being. When finished, I select an angular dimension and then use SELECTSIMILAR. It will not select linear, rotated, diameter or radius dimensions. Then go into PROPERTIES and delete the " mark there, under the Primary Units section, and change all at once.

[nestly2]

Did you watch the screencast demo?   It shows how to set up the dimstyle according to the type of dimension...

[Kent1Cooper]

---

@steve216586 wrote:

We use the " suffix for inches here. Yes it can be cumbersome to have the degree symbol and also the " mark.

My solution has been to work as normal and ignore it, for the time being. When finished, I select an angular dimension and then use SELECTSIMILAR. It will not select linear, rotated, diameter or radius dimensions. Then go into PROPERTIES and delete the " mark there, under the Primary Units section, and change all at once.

---

I agree that you should set up different "families" so that angular Dimensions don't get the suffix that linear ones do.  But for those already existing, you can reduce that process to a blanket selection [minimally tested]:

(defun C:ADSS (/ ss sss n dim); = Angular Dimension Strip Suffix
  (if (setq ss (ssget "_:L" '((0 . "DIMENSION")))); accept Dimensions only [including types not to strip]
    (progn ; then
      (setq sss (ssadd)); Selection Set to Strip [initially empty]
      (repeat (setq n (sslength ss))
        (setq dim (ssname ss (setq n (1- n))))
        (if (wcmatch (cdr (assoc 100 (reverse (entget dim)))) "*Angular*"); only Angular varieties
          (ssadd dim sss)
        ); if
      ); repeat
      (if (> (sslength sss) 0); were there any Angular ones?
        (command "_.dimoverride" "dimpost" "." "" sss ""); then -- remove suffix
      ); if
    ); progn
  ); if
); defun

That will strip any suffix from all selected Angular Dimensions [only], so if there's ever anything other than the inch mark that should stay, don't use it on such Dimensions.

[steve216586]

nestly2,

I watched it but that is not a solution for me. I can't change the dimstyle. I can only modify dimension entities through properties. That method would be too advanced for the rest of my office.

Thanks for the script but again, that is too advanced for my office. I have several users who brag about being trained on DOS but still refuse to use LISP or associated dims. They also scroll scale in PS. "Eyeball" dims instead of DIMREASSOCIATE.

I was just trying to offer my simple way of dealing with the OP problem on the fly, as simply and efficiently as most of us have to do.

[Kent1Cooper]

---

@steve216586 wrote:

.... 

I watched it but that is not a solution for me. I can't change the dimstyle. I can only modify dimension entities through properties. That method would be too advanced for the rest of my office.

Thanks for the script but again, that is too advanced for my office. I have several users who brag about being trained on DOS but still refuse to use LISP or associated dims. They also scroll scale in PS. "Eyeball" dims instead of DIMREASSOCIATE.

....

---

I think you need to tell them they must use more appropriate methods, or have some of them fired because they're wasting your, and therefore the company's, time and therefore money, not to mention potentially that of other companies who may use your company's drawings.

If by "script" you're referring to my ADSS command, it's not a Script [that has a specific, and different, meaning in AutoCAD].  If you arrange things so that it's loaded in all drawings [not difficult to do], it's just another command, and learning and using it is no more "advanced" than, say, the Line command.

[steve216586]

"I think you need to tell them they must use more appropriate methods, or have some of them fired because they're wasting your, and therefore the company's, time and therefore money, not to mention potentially that of other companies who may use your company's drawings."

I hear what you're saying Kent. Trust me I feel the same way. Unfortunately most Senior Engineer Managers I've come across don't feel the same way. 

(Well, at least the ones not doing design work as consulting work. At this and my previous job, we create drawings for sales support and fabrication/manufacturing. All our drawings are in house or mere dog and pony representations for the customers to review and approve. They are not used by anyone else or submitted to an approving authority, like a DOT for instance.) 

Anyway, about the management mandating an adherance to any CAD standards... As long as projects go out the door and our people can manufacture the models, they are happy. No complaints, no comment, sort of deal. They would never fire someone for not using appropriate methods. As far as wasting time, I find most managers are very lenient in that aspect. Unless deadlines are missed, nothing is said. Even then, a deadline missed which can be explained to the customer and accepted, is often forgotten. I've seen both companies ignore overrun costs and riders due to missed deadlines. 

Most management personnel today care more about design then CAD standards.

e.g. I set up a drawing for an associate engineer with viewports and annotative dimensions. Completed the entire design model. Come to find out he's still using AutoCAD2000 and couldn't figure out how to show the dimensions in paperspace. When I told him to upgrade to a version which "sees" annotative objects, he scoffed. Then told our manager that I screwed his timetable up because now he'd have to go back and recreate the drawing from scratch so he could work with it "properly". I have never been asked to help him since.

It is a grim view of the future. Sad part about it, is that for it to get better, we have to wait until all the "old dogs" are retired before we get competent (with current technology knowledge) people to replace them. They are in the places of authority just by the nature of their age. I'm not young but I have progressed and accepted change as inevitable. If you're not going forward with technology, you are getting passed by everyone else.

sorry for the rant ;-(

[Rellik28031]

That was it. Thank you.

--
[image: photo]
Kevin Yantorno
Drafter
T: 1-877-803-2282
*•* P.O. Box 562206
Charlotte, NC 28256
*•*Www.Deciron.Com

[Rellik28031]

I ended up fixing all of the dimension styles that I use by creating a two
child dimensions under each main dimension style. One for linear
dimensions with the inch mark and one for angular dims without the inch
mark.

--
[image: photo]
Kevin Yantorno
Drafter
T: 1-877-803-2282
*•* P.O. Box 562206
Charlotte, NC 28256
*•*Www.Deciron.Com

[Kent1Cooper]

If you just set the Dimension text to use Architectural or Engineering Units, the inch(es) mark will be there in linear dimensions and not in angular dimensions, without your needing to either specify a suffix or have parent and child Dimension styles.

[pfilters]

First off, my feelings about AutoCAD's current method of solving this problem is documented in great detail at this other post http://forums.autodesk.com/t5/autocad-2013-2014-2015-2016/dimension-style-manager-quot-primary-units...

Second, I really love the idea of using a LISP to strip Angular dimensions of their suffix.  I figured it could be done but wasn't sure how.  I implemented your LISP a few minutes ago and found it clears all suffixes on Angular dims and not just " marks, while retaining the degree symbol, of course.  I decided to take it to the next level and add the "ADSS" command to my Angular dim button (see attached image, highlighted section).  With this button, you create an angular dim as usual but then it runs the ADSS command, chooses the "last" object created, and then strips the Angular dimension of it's suffix, and all of it happens in the background.  This way, you don't need to remember to run the routine later, or even remember the key strokes for the ADSS command.  The only drawback I see at the moment is not being able to repeat the dimension command with a right-click, "Enter", or "Spacebar"; you have to click the button each time.

This also works with "ALL" in place of "LAST" if you want to be a little more thorough and change ALL angular dims in the drawing including previously created angular dims every time you create a new angular dim.  But if someone needs to retain some angular dimensions with suffixes, then they would need to use the "LAST" version and create an additional button for doing "standard" angular dims, or just make the "LAST" button a new button and leave the standard one alone.

This LISP is the workaround I need to resolve my concerns of creating 5 child dim styles and ignore the one with the problem, angular dims.

Thank you, thank you, thank you.

[Kent1Cooper]

---

@pfilters wrote:

....  I implemented your LISP ....  I decided to take it to the next level and add the "ADSS" command to my Angular dim button (see attached image, highlighted section).  ....  The only drawback I see at the moment is not being able to repeat the dimension command with a right-click, "Enter", or "Spacebar"; you have to click the button each time.

....

---

You could combine the elements of that command-macro button into a defined command, have it loaded automatically by acaddoc.lsp, and put that new command name into the button, instead of what you have there now.  Then you'd be able to either pick the button to get it or type in its command name, and you could hit Enter/space to repeat it.

Do you know enough to make that kind of definition?

[Kent1Cooper]

---

@pfilters wrote:

First off, my feelings about AutoCAD's current method of solving this problem is documented in great detail at this other post http://forums.autodesk.com/t5/autocad-2013-2014-2015-2016/dimension-style-manager-quot-primary-units...

....

---

As for that, I truly believe the "problem" is in having any Dimension Style defined with a "forced" inch-mark suffix!  Re-read Post 12 on this thread.  If you get resistance to changing the Style definition, re-read my first paragraph in Post 8.

[pfilters]

We'll have to agree to disagree on accepting a "forced" suffix.  I don't need/want "feet and inches", just inches, and the only way to do that is a Fractional dim style.  So, I need to add the " mark.  Plus there's the argument for dimensioning in metric.  But let's get past all that.

I tried to create the combo command of an angular dim and your ADSS and it failed.  I can make most LISP routines I need, but I am still self taught and very limited in complex routines.  Here's what i wrote:

(defun c:ADWSS ()
(command "_dimangular" pause pause pause "adss" "last" "")
)

I have your original string previously defined for ADSS.  The command starts off just fine, but for some reason it doesn't recognize ADSS as a command inside this routine.  I can abort the routine and just type ADSS directly into the command line and it works.  Could you please provide the correct wording?  Thanks in advance.

[Kent1Cooper · Accepted solution]

---

@pfilters wrote:

.... 

I tried to create the combo command of an angular dim and your ADSS and it failed. ....

(defun c:ADWSS ()
(command "_dimangular" pause pause pause "adss" "last" "")
)

... for some reason it doesn't recognize ADSS as a command inside this routine. ....

---

That's because inside a (command) function, you can use only actual AutoCAD command names, not (defun)'d ones.  I suggest combining the core of what ADSS does with the making of an angular dimension, and it can be a lot simpler, since it doesn't need to deal with User selection, or filtering, or multiple objects.  Try this [untested]:

(defun c:ADWSS ()
  (command "_.dimangular")
  (while (> (getvar 'cmdactive) 0) (command pause))
  (command "_.dimoverride" "dimpost" "." "" (entlast) ""); remove suffix
); defun

That (while) function allows the possibility of a DIMANGULAR command that uses some option resulting in the need for more than three inputs -- it waits for User input until the command is completed, however many inputs that takes, and only then moves on.

You could even make that a replacement definition of the DIMANGULAR command itself, if you want, so you don't need to remember the different name, and/or can use the DIMANG alias, and/or can pick it from a menu item:

(command "_.undefine" "DIMANGULAR")

(defun c:DIMANGULAR ()
  (command "_.dimangular"); invoke the native version of the command
  (while (> (getvar 'cmdactive) 0) (command pause))
  (command "_.dimoverride" "dimpost" "." "" (entlast) ""); remove suffix
); defun

[pfilters]

I would mark it as a solution but can't; a "Kudos" will have to do.
Thanks so much.

[Kent1Cooper]

---

@pfilters wrote:
I would mark it as a solution but can't; a "Kudos" will have to do.
Thanks so much.

---

We Expert Elite members wield the awesome power to mark things as Solutions even in threads we didn't start.  I only very rarely do so with with my own Posts, but this seems close enough to exactly in line with the original question that I hope it's justified.  I also hope the OP notices that there's a "pre-emptive" solution here now.  Use it in good health.

[akamoo321]

Oh my gosh ive been searching for 3 days  for this answer! THANK YOU!!