Dale,
Or try this lisp program. Converts a selection set of arcs, circles, splines
or ellipses to lwplines with a user defined number of vertices. Don't thank
me. I only tweaked it. Thanks goes to Andrzej Gumula.
;based on spline2poly.lsp by Andrzej Gumula - customization NG 9/27/02
;modified to include ellipses, circles and arcs - added undo
;needs A2k or above
(defun c:Curve2Pline (/ Fit SSet Count Delta Measure Pts Mark)
(defun *error* (Msg)
(cond
((or (not Msg)
(member Msg '("console break"
"Function cancelled"
"quit / exit abort"))))
((princ (strcat "\nError: " Msg)))
) ;cond
(UndoEnd)
(princ)
) ;end error
(vl-load-com)
;by John Uhden
(setq *acad* (vlax-get-acad-object))
(defun UndoBegin ()
(vla-StartUndoMark (vla-get-activedocument *acad*))
)
(defun UndoEnd ()
(vla-EndUndoMark (vla-get-activedocument *acad*))
)
;by Joe Burke with lotsa help
(defun SSAfterEnt (ent / ss* entlst)
(and
(setq ss* (ssadd))
(while
(setq ent (entnext ent))
(setq entlst (entget ent))
(if
(and
(not
(wcmatch (cdr (assoc 0 entlst)) "ATTRIB,VERTEX,SEQEND")
) ;not
(eq (cdr (assoc 410 entlst)) (getvar "ctab"))
) ;and
(ssadd ent ss*)
) ;if
) ;while
) ;and
ss*
) ;end
(defun MakePoly ()
(entmake
(append
(list
'(0 . "LWPOLYLINE") '(100 . "AcDbEntity") '(100 . "AcDbPolyline")
(cons 6 (vla-get-linetype Obj)) (cons 62 (vla-get-color Obj))
(cons 8 (vla-get-layer Obj)) (cons 90 (length Pts))
(if (vlax-curve-isclosed Obj) (cons 70 1) (cons 70 0))
)
(mapcar '(lambda (x) (cons 10 x)) Pts)
)
)
);end MakePoly
(defun StatLayer (Name Id)
(/= Id
(logand Id
(cdr (assoc 70 (entget (tblobjname "layer" Name))))
)
)
);end StatLayer
(UndoBegin)
(setq Mark (entlast))
(princ "Select circles, arcs, ellipses or splines: ")
(cond
((setq SSet (ssget ":L" '((0 . "SPLINE,ELLIPSE,CIRCLE,ARC"))))
(while (not (and (>= Fit 3) (<= Fit 500)))
(initget 7)
(setq Fit (getint "\nEnter number of segments [3 - 500]: "))
) ;while
(repeat (setq Count (sslength SSet))
(setq Count (1- Count)
Obj (vlax-ename->vla-object (ssname SSet Count))
Delta (/ (vlax-curve-getdistatparam Obj
(vlax-curve-GetEndParam Obj)) Fit)
Measure 0.0 Pts nil)
(repeat (1+ Fit)
(setq Pts (cons (vlax-curve-getpointatdist Obj Measure) Pts)
Measure (+ Measure Delta))
);end repeat
(cond
((StatLayer (vla-get-layer Obj) 4)
(MakePoly)
(vla-delete Obj))
);end cond
);end repeat
)
(T (prompt "\nCurves not selected "))
) ;cond
(cond ((> (sslength SSet) 0)
(princ (strcat "\nNumber of curves converted: "(itoa (sslength SSet))))
(sssetfirst nil (SSAfterEnt Mark))) ;select
) ;cond
(*Error* nil)
(princ)
);end
> Can you turn an ellipse into a pline and give it a thickness?
>
> --
> Dale Jarvis, Engineering Technologist
> Gairns Santos Engineering Inc.
> Ph. (250) 562-0330
> Fax. (250) 562-0331
