Community
Is there a chance that you have localised or redefined the distance symbol?
Does the error still occur if you restart AutoCAD with no customisations loaded?
Could you post the exact error message as it appears on the command-line?
I would suggest the following modifications:
(defun c:mydist ( / 2dd ang del dis pt1 pt2 )
;; Define function, declare local variables.
;; To understand why variable localisation is important
;; see http://bit.ly/15Qw104
(if ;; IF the following expression returns a non-nil value
(and
;; All of the enclosed expressions must return a non-nil value for AND to return T.
;; AND will cease evaluation when an expression returns nil.
(setq pt1 (getpoint "\nPick 1st point: "))
;; Prompt the user for the 1st point
(setq pt2 (getpoint "\nPick 2nd point: " pt1))
;; Prompt the user for the 2nd point, rubber-band to 1st point
) ;; end AND
(progn
;; Evaluate the following expressions and return the result
;; of the last expression evaluated. PROGN is used as a
;; wrapper function so that we can pass multiple expressions
;; to the IF function as a single argument constituting the
;; 'then' parameter.
(setq ;; Assign values to the following symbols:
dis (distance pt1 pt2) ;; 3D distance
ang (angle (list (car pt1) (cadr pt1)) (list (car pt2) (cadr pt2))) ;; Angle in XY
2dd (distance (list (car pt1) (cadr pt1)) (list (car pt2) (cadr pt2))) ;; 2D distance
del (mapcar '- pt2 pt1) ;; Delta vector
) ;; end SETQ
(princ
;; Print the following string to the command-line
;; To understand the difference between princ, prin1 & print
;; see http://bit.ly/1chjetS
(strcat ;; Concatenate the following strings:
"\nDistance = " (rtos dis 4 8) " (" (rtos dis 2 8) "), "
"Angle in XY Plane = " (angtos ang 0 8) ", "
"Angle from XY Plane = " (angtos (atan (caddr del) 2dd) 0 8)
"\nDelta X = " (rtos (car del) 4 8) " (" (rtos (car del) 2 8) "), "
"Delta Y = " (rtos (cadr del) 4 8) " (" (rtos (cadr del) 2 8) "), "
"Delta Z = " (rtos (caddr del) 4 8) " (" (rtos (caddr del) 2 8) ")"
) ;; end STRCAT
) ;; end PRINC
) ;; end PROGN
;; If we had an 'else' parameter, we would insert it here.
) ;; end IF
(princ) ;; Suppress the return of the last evaluated expression
) ;; end DEFUN
Please ask if you are unsure of any of the comments in the code.
Lee
@Lee_Mac wrote:
....
(princ
;; Print the following string to the command-line
;; To understand the difference between princ, prin1 & print
;; see http://bit.ly/1chjetS
....
Largely a matter of preference, but personally, I use the (prompt) function for this kind of thing. The (prin...) functions are built for the possibility of writing to an external file, which is overhead in this situation, and they not only print to the command line but also return the string in case you are writing it to a file. The latter of those outcomes serves no purpose here. Prompting the user is exactly what you're doing, so you may as well use the function that's intended expressly for that.
Kent Cooper, AIA 
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
