Here's the lisp to offset entities out of a block - written my Mel Franks back in"07. Mel made this for me to offset to a layer called "Detail" (or maybe I added that part myself?). Anyway, you can take that part out or change the layer if you need to.
For some wierd reason, the add attachment button below will not allow me to upload the lisp file claiming "The contents of the attachment doesn't match its file type" which is not true. Never had this problem before, so anyway I'll paste it in and you can copy it to a blank file and save it as OSB.lsp
;;OFFSET ENTITIES FROM BLOCK OBJECTS AND
;;PUT THEM ON LAYER DETAIL AND "BYLAYER"
;;BY MEL FRANKS FOR RAPIDCAD 11-14-07
(defun c:OSB (/ *error* z blk cmd-sv os-sv)
(defun *error* (errmsg / x)
(princ "Error: ")
(princ errmsg)
(setvar 'cmdecho cmd-sv)
(setvar 'osmode os-sv)
(if #blk-ent-lst#
(foreach x #blk-ent-lst#
(if (not (vlax-erased-p x))
(vla-delete x)
)
)
)
(if #off-obj#
(if (not (vlax-erased-p #off-obj#))
(vla-delete #off-obj#)
)
)
(princ)
)
(vl-load-com)
(setq cmd-sv (getvar "cmdecho")
os-sv (getvar "osmode")
#blk-ent-lst# '()
#off-obj# nil
)
(setvar 'cmdecho 0)
(setvar 'osmode 0)
(if (not (tblsearch "layer" "DETAIL"))
(vl-cmdf "_.layer" "n" "DETAIL" "")
)
(if (not (tblsearch "layer" "HIDDEN_BLOCK"))
(vl-cmdf "_.layer" "n" "HIDDEN_BLOCK" "")
)
(vl-cmdf "_.layer" "f" "HIDDEN_BLOCK" "")
(if (null #off-dist#)
(setq #off-dist# 0.375)
)
(initget 6)
(setq x (getdist
(strcat "\nOffset distance: <" (rtos #off-dist#) "> ")
)
)
(if x
(setq #off-dist# x)
)
(while (setq z (entsel "\nSelect object to offset: "))
(cond
((setq blk (get-valid-object z))
(setq #off-obj# (get-offset-obj blk))
(initget 1)
(setq dest (getpoint "\nSelect point on side to offset: "))
(vl-cmdf "_.offset"
#off-dist#
(vlax-vla-object->ename #off-obj#)
dest
""
)
(vl-cmdf "_.chprop"
(entlast)
""
"la"
"DETAIL"
"c"
"BYL"
"lt"
"BYL"
""
)
(vla-delete #off-obj#)
)
)
)
(setvar 'cmdecho cmd-sv)
(setvar 'osmode os-sv)
(princ)
)
;function to get initial offset object
;accepts return value from (entsel)
;
(defun get-offset-obj (e / obj point-on-obj o-obj x orig-layer m)
(setq obj (vlax-ename->vla-object (car e))
point-on-obj (osnap (cadr e) "nea")
#blk-ent-lst# (vlax-invoke obj 'Explode)
o-obj nil
orig-layer (cdr (assoc 8 (entget (car e))))
)
(vl-cmdf "_.chprop" (car e) "" "la" "hidden_block" "")
(setq m (nentselp point-on-obj))
(vl-cmdf "_.chprop" (car e) "" "la" orig-layer "")
(setq m (ck-for-vertex (car m))
o-obj (vla-copy (vlax-ename->vla-object m))
)
(foreach x #blk-ent-lst# (vla-delete x))
o-obj
)
;if a vertex (polyline) is found
;get base ename
;
(defun ck-for-vertex (p / v)
(setq v nil)
(if (= (cdr (assoc 0 (entget p))) '"VERTEX")
(while (and (setq p (entnext p))
(/= (cdr (assoc 0 (setq v (entget p)))) '"SEQEND")
)
)
)
;return pline ename or just return input
(if v
(cdr (assoc -2 v))
p
)
)
;get a valid block or single entity
;accepts return value from (entsel)
;
(defun get-valid-object (ent / sub-ent sub-type flag nlst last-ent)
(setq flag nil)
(cond
((and
(= (vla-get-objectname
(setq obj (vlax-ename->vla-object (car ent)))
)
"AcDbBlockReference"
)
(vlax-method-applicable-p obj 'explode)
(equal
(vla-get-XScaleFactor obj)
(vla-get-YScaleFactor obj)
(vla-get-ZScaleFactor obj)
)
)
(setq sub-ent (vlax-ename->vla-object
(car (setq nlst (nentselp (cadr ent))))
)
sub-typ (vla-get-objectname sub-ent)
)
(if (member sub-typ
'("AcDb2dVertex" "AcDbPolyline"
"AcDbArc" "AcDbLine"
"AcDbCircle" "AcDbSpline"
"AcDbEllipse"
)
)
(if (< (length (last nlst)) 2)
(setq flag ent)
(princ "\nCannot offset from a nested block")
)
(princ "\nThis object cannot be offset")
)
)
(t
(if (vlax-method-applicable-p
(vlax-ename->vla-object (car ent))
'offset
)
(progn
(initget 1)
(setq dest (getpoint "\nSelect point on side to offset: ")
last-ent (entlast)
)
(vl-cmdf "_.offset" #off-dist# (car ent) dest "")
(if (not (eq last-ent (entlast)))
(vl-cmdf "_.chprop"
(entlast)
""
"la"
"DETAIL"
"c"
"BYL"
"lt"
"BYL"
""
)
)
)
(princ "\nThis object cannot be offset")
)
)
)
flag
)
(princ)
ADN CAD Developer/Operator
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
