Community
Everything entered at the keyboard is ASCII (it includes numbers, letters, and a number of non-printing characters). If you mean differentiating between numeric and alphanumeric content, yes - there's a couple of ways of doing that. You can try converting the input into an integer via (atoi ...), but there's a few limitiations. And you can convert the input string to a list of ASCII codes; ASCII groups its characters together, so you can range-test each ASCII value to see if its a number or not.
----------------------------------
If you are going to fly by the seat of your pants, expect friction burns.
"I don't know" is the beginning of knowledge, not the end.
If you are going to fly by the seat of your pants, expect friction burns.
"I don't know" is the beginning of knowledge, not the end.
@smaher12 wrote:
I am messing around with a lisp that will draw grid bubbles and was wonder if instead of doing (setq an (getkword "\nSpecify grid type [Alpha/Numeric]: ")) can the getstring fuction be used to determine if the user enters ascii do this and if the user entered a integer do that? Recommendations?
One way to do that, if the return of (getstring) is saved to a variable called 'str':
(if
(= str (itoa (atoi str))); convert to integer and back to string -- the same?
(...then, it's an integer...)
(...else, it's something else, presumably a letter...)
)
The "something else" could include an empty string [Enter in response to (getstring)], or a combination such as "3B", as well as the expected things like "A". So if you want to protect against certain kinds of invalid input, you might need to make it more sophisticated.
Kent Cooper, AIA 
@smaher12 wrote:
I managed to patch this together. Suggestions?
Do you think you need to do anything to prevent an entry such as "3B"? If someone typed that in, 'glt' would be 3, and it would proceed as if they had typed in just "3". Similarly, if they typed "B8", it would I think use that for the first one, then "C9", then "D:", then "E;", etc. It would be possible [as in another recent thread] to limit it to only numbers or only alphabetic characters, place a limit on the number or characters, by testing what the User typed with (wcmatch), and asking again if they made an invalid entry.
Apart from the possibility of the User answering the prompt with Escape, 'glt' is going to be either 0 or not, so you can consolidate your two (if) functions into one, with 'then' and 'else' expressions:
....
(if (/= glt 0)
(progn ; then
(command "TEXT" "M" pt "" "0" glt)
(setq glt (1+ glt))
); progn [then]
(progn ; else
(command "TEXT" "M" pt "" "0" str)
....
); progn [else]
); if
....
Kent Cooper, AIA
@smaher12 wrote:Suggestions?
I would suggest the following for your consideration:
(defun c:tag ( / fun ins ocs str uxa )
(while
(not
(or (= "" (setq str (getstring "\nSpecify grid line tag: ")))
(wcmatch str "~*[~0-9]*")
(wcmatch str "~*[~a-zA-Z]*")
)
)
(princ "\nPlease enter either letters or numbers.")
)
(if (/= "" str)
(progn
(if (wcmatch str "~*[~0-9]*")
(setq fun (lambda ( x ) (itoa (1+ (atoi x)))))
(setq fun LM:A++)
)
(setq ocs (trans '(0.0 0.0 1.0) 1 0 t)
uxa (angle '(0.0 0.0 0.0) (trans (getvar 'ucsxdir) 0 ocs t))
)
(while (setq ins (getpoint "\nSpecify point <Done>: "))
(entmake
(list
'(00 . "TEXT")
'(72 . 4)
'(73 . 0)
(cons 001 str)
(cons 050 uxa)
(cons 007 (getvar 'textstyle))
(cons 040 (getvar 'textsize))
(cons 010 (trans ins 1 ocs))
(cons 011 (trans ins 1 ocs))
(cons 210 ocs)
)
)
(setq str (fun str))
)
)
)
(princ)
)
;; Alpha++ - Lee Mac
;; Increments an alphabetical string by one, e.g. AZ => BA
;; a - [str] alphabetical string
(defun LM:A++ ( a )
( (lambda ( f ) (vl-list->string (reverse (f (reverse (vl-string->list a)) t))))
(lambda ( l x )
(cond
( (null l) (if x '(65) '(97)))
( (= 090 (car l)) (cons 65 (f (cdr l) t )))
( (= 122 (car l)) (cons 97 (f (cdr l) nil)))
( (cons (1+ (car l)) (cdr l)))
)
)
)
)
(princ)
On a related note, you might also be interested in my Incremental Numbering Suite program.
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
