batch remove standard files

[scgham]

I use templates that are associated to a dws file, so the dws files are associated to all final dwgs, is there a way to batch remove them before sending files to the client, i tried batch standard checker but did not find an option for that.
I posted that issue in the 2005 group but to no avail.
Hope that some one have a code for doing that, or even better a direct way,
Thanks.

[Joris]

If you put the process to remove the files in a script, then it is possible to batch-process them with one of the following programs:

ScriptEeze: http://www.xanadu-limited.com/scripteeze/scripteeze.htm

MultiBatch: http://www.multibatch.com

Regards,
Joris

[Anonymous]

References to .dws files associated with a drawing are stored in a dictionary named
"AcStStandard".

;; Function: delete a dictionary from the dictionary collection.
;; Argument: string - dictionary name.
;; Returns: T if successful, otherwise nil.
(defun DeleteDictionary (dictname / dicts dictobj)
(setq dicts
(vla-get-dictionaries
(vla-get-activedocument
(vlax-get-acad-object))))
(if
(not
(vl-catch-all-error-p
(setq dictobj
(vl-catch-all-apply
'vla-item (list dicts dictname)))))
(not (vla-delete dictobj))
)
) ;end

Example:
Command: (DeleteDictionary "AcStStandard")
T

How that might be used in batch mode is your choice. ObjectDBX is one option.

Joe Burke


wrote in message news:5238591@discussion.autodesk.com...
I use templates that are associated to a dws file, so the dws files are associated to
all final dwgs, is there a way to batch remove them before sending files to the
client, i tried batch standard checker but did not find an option for that.
I posted that issue in the 2005 group but to no avail.
Hope that some one have a code for doing that, or even better a direct way,
Thanks.

[scgham]

and how to delete all?
thanks

[Anonymous]

If you mean delete all standards files attached to a drawing, that will do it.

Joe Burke


wrote in message news:5239742@discussion.autodesk.com...
and how to delete all?
thanks

[scgham]

ok, but how?
(DeleteDictionary " ") or what?
thanks again.

[Anonymous]

Here's the example from my first post.

Example:
Command: (DeleteDictionary "AcStStandard")
T


wrote in message news:5239794@discussion.autodesk.com...
ok, but how?
(DeleteDictionary " ") or what?
thanks again.

[Anonymous]

You're welcome.

Check here in an hour or so. I'll post an example of running it on all open files.

Joe Burke

wrote in message news:5239794@discussion.autodesk.com...
ok, but how?
(DeleteDictionary " ") or what?
thanks again.

[scgham]

Ah, i got it now, i had to try it to know how it works.
Thanks a lot for your time.

[Anonymous]

I often use this operate on open files method rather than using
ObjectDBX. The files in question may already be open, in which case,
ObjectDBX doesn't apply. Or I may need to check what happened in
each file, so I might as well open them first.

It also serves as a file selection method. More code would be
needed otherwise.

;; 7/18/2006
;; Delete all CAD standards .DWS files attached to all open files.
;; If found, removes the "AcStStandard" dictionary from each file.
;; Returns the number of files modified.
;; Note, modified files are not saved.
(defun c:DeleteStandards ( / cnt documents dicts)
(setq cnt 0
documents (vla-get-documents (vlax-get-acad-object))
)
(vlax-for doc documents
(setq dicts (vla-get-dictionaries doc))
(if
(not
(vl-catch-all-error-p
(setq dictobj
(vl-catch-all-apply
'vla-item (list dicts "AcStStandard")))))
(progn
(vla-delete dictobj)
(setq cnt (1+ cnt))
)
)
)
(princ (strcat "\nNumber of documents modified: " (itoa cnt)))
(princ)
) ;end

Example:
Command: DeleteStandards
Number of documents modified: 1

Joe Burke

[scgham]

Thanks again Joe, you have been very helpfull.

[Anonymous]

My pleasure. I hope it suits your needs.

Joe Burke

wrote in message news:5239990@discussion.autodesk.com...
Thanks again Joe, you have been very helpfull.