Community
The "malformed list on input" usually means unbalanced brakets, therefore nothing to do with localize variables.
Post your code, will be easier to assist.
Al the sites mentioned by you, are very good places to learn, but don't forget the AutoLISP Reference, the AutoLISP Devoloper's Guide and the AutoLISP Tutorial from the Help files.
Henrique
Firstly, thank you for your compliments for my site - I hope my tutorials are clear & somewhat comprehensible 
As Henrique points out, the 'malformed list on input' error indicates unbalanced parentheses - specifically, you have too few closing parentheses for the number of open parentheses. I have written an overview explaining the possible meaning of some of the most common error messages which you may find here for your reference.
To help you to find the imbalance, if you are using the Visual LISP IDE* (and if not, I would strongly suggest that you do use it!) note that you can double-click before an open parenthesis or after a closing parenthesis in order to highlight all code enclosed by that expression:
*If you are new to the Visual LISP IDE, here are some tutorials to get you started:
The Visual LISP Editor - Part 1
The Visual LISP Editor - Part 2
An Introduction to the Visual LISP IDE
Retrieving Information About a Function
A few things I notice immediately:
You store the value of the osmode system variable using the variable 'oldosm', but in the *error* function, you use a variable 'osm':
(defun *error* ( msg )
(if osm (setvar 'osmode osm))
...
)
...
(setq oldosm (getvar "Osmode"))
You have an extra closing parenthesis which ends the function definition (defun) immediately after storing & setting the system variable values:
) ;End of storing old user settings
This should get you going in the right direction:
(defun c:cmb ( / *error* cmd ins osm )
;; Define local error handler to reset CMDECHO & OSMODE
(defun *error* ( msg )
(if cmd (setvar 'cmdecho cmd))
(if osm (setvar 'osmode osm))
(if (not (member msg '("Function cancelled" "quit / exit abort")))
(princ (strcat "\nError: " msg))
)
(princ)
)
;; Store current values of OSMODE & CMDECHO system variables
(setq osm (getvar 'osmode)
cmd (getvar 'cmdecho)
) ;; end setq
;; Set the sys vars to their required values
(setvar 'osmode 3)
(setvar 'cmdecho 0)
;; Initialise keyword options
(initget "Yes No")
;; Prompt user
(if (= "Yes" (getkword "\nInsert Pkt_Radius_0.3583RH? [Yes/No] <No>: "))
;; Prompt user for insertion point
(if (setq ins (getpoint "\nPick insertion point: "))
(command
"_.-insert"
;| *=explode |; "*PktRadius3583RH" ;; Program assumes this block exists
"_S" 1.0 ;; Block Scale = 1
"_R" 0.0 ;; Block Rotation = 0
"_non" ;; Ignore Object Snap for the next input
ins
) ;; end command
) ;; end if
) ;; end if
;; Initialise keyword options
(initget "Yes No")
;; Prompt user
(if (= "Yes" (getkword "\nInsert Pkt_Radius_0.3583LH? [Yes/No] <No>: "))
(if (setq ins (getpoint "\nPick insertion point: "))
(command
"_.-insert"
;| *=explode |; "*PktRadius3583LH" ;; Program assumes this block exists
"_S" 1.0 ;; Block Scale = 1
"_R" 0.0 ;; Block Rotation = 0
"_non" ;; Ignore Object Snap for the next input
ins
) ;; end command
) ;; end if
) ;; end if
;; Reset sys vars
(setvar 'cmdecho cmd)
(setvar 'osmode osm)
(princ "\nEnd of program.")
(princ) ;; Supress the return of the last evaluated expression
) ;; end defun
(princ "\n<Type \"cmb\" To Start Block Insert Program>") ;; Loading expression
(princ) ;; Supress the return of the last evaluated expression on load
Note that for the sake of simplicity for your understanding, the above program does not test whether the blocks exist.
Lee
Thank you Henrique!
The program could be enhanced further, but I didn't want to deviate too far from the original code so as not to overwhelm the OP.
Lee
@cncah wrote:
Thank you very much for the fix to the program
You're welcome!
@cncah wrote:I had seen the trick of using the * in front of the filename to explode it upon insertion before in my research, and have tried it many times, but can never get it to work. Doesn't seem to matter if I describe the full path to the file, or if I move the files to the active document and just call out the filename without inputting the path info.
The use of the asterisk only works when supplying only the block name to the -INSERT command (i.e. when the block is either already defined in the drawing, or the drawing file for the block resides in an AutoCAD Support File Search Path).
@cncah wrote:This is what I ended up with and it runs great:
(defun c:cmb ( / *error* cmd ins osm )
...
)
Excellent - I'm glad you were able to get the program working as required.
A couple of minor suggestions:
1) You could combine the two command expressions into one, removing the need for progn:
(progn
(command
"_.-insert"
"PktRadius3583RH"
"_S"
"1.0" ;; Block Scale = 1
"_R"
"0.0" ;; Block Rotation = 0
"_non" ;;Ignore osnaps for block insertion
ins
) ;; end command
(command "_explode"
"last") ;;Explode last inserted block
becomes:
(command
"_.-insert"
"PktRadius3583RH"
"_S" "1.0"
"_R" "0.0"
"_non" ins
"_.explode"
"_last"
)
2) Instead of separately prompting the user for an insertion point, you could take advantage of the ghosting effect afforded by the -INSERT command, i.e. this:
(initget "Yes No")
(if (= "Yes" (getkword "\nInsert Pkt_Radius_0.3583RH? [Yes/No] <No>: "))
(if (setq ins (getpoint "\nPick insertion point: "))
(progn
(command
"_.-insert"
"PktRadius3583RH"
"_S"
"1.0" ;; Block Scale = 1
"_R"
"0.0" ;; Block Rotation = 0
"_non" ;;Ignore osnaps for block insertion
ins
) ;; end command
(command "_explode"
"last") ;;Explode last inserted block
)
) ;; end if
) ;; end if
Becomes:
(initget "Yes No")
(if (= "Yes" (getkword "\nInsert Pkt_Radius_0.3583RH? [Yes/No] <No>: "))
(if (vl-cmdf "_.-insert" "PktRadius3583RH" "_S" "1" "_R" "0" "\\")
(command "_.explode" "_last")
)
)
@cncah wrote:I appreciate the help with the training and getting me out of the rut I was in. As always Lee you have helped me out tremendously and I thank you. I'm going to start adding all the other blocks that I need to this program and will refer to it as my template when writing new programs. Thank You Very Much!!!
Thank you for your gratitude for my time & assistance - you are most welcome.
@cncah wrote:
...
(setq oldlayername '(Pkt_Radius_)) ;;Assigns the inserted block's layer name to a variable
(setq newlayername (strcat (oldlayername thk1))) ....
...
Layer names are text strings, and that's what (strcat) will want to work with. Try changing the first line above to:
(setq oldlayername "Pkt_Radius_")
Kent Cooper, AIA 
@cncah wrote:
Ok, I got it to set the Pkt_Radius_ to the oldlayername value. But I still can't get the Pkt_Radius_ and a real number(0.3583) to add together. ....
I guess, I just need to know how to add a set of text to a real number so I can set that to a new value and use that to rename the layer.
I hadn't looked closely enough to notice that what you were tacking on was a number. In that case:
(setq newlayername (strcat (oldlayername (rtos thk1 2 4))))
The 2 is for decimal mode. The 4 is the number of decimal places, which will flesh it out with trailing zeros when appropriate, as in some of your examples.
Kent Cooper, AIA
I didn't notice the extra left parenthesis you had in there, preceding the oldlayername variable name [and corresponding extra right parenthesis at the end]. Try this:
(setq newlayername (strcat oldlayername (rtos thk1 2 4)));; no ( before oldlayername
Kent Cooper, AIA
@cncah wrote:
....Although when I check the value in vlide, it shows up in quotation marks.
"Pkt_Radius_0.3583"
....
(command "-Rename"
"Layer"
oldlayername
"" ;;Inputs what the old layer name was
newlayername
"" ;;Inputs what the new layer name will be
) ;;End of layer rename
....
Yes, Layer names are text strings, and those always display with double-quotes at the ends.
The Layer names, both old and new, will be "registered" by the end of their text strings, and don't need an additional Enter for that. Try removing the orange lines, which I believe you do not need.
Kent Cooper, AIA
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
