Visual LISP, AutoLISP and General Customization
Doesn't look too difficult, with a series of (write-line) functions including (strcat) functions in them. But first:
In what form are the points whose coordinates you want to export? A list of point lists? If so, do they include Z coordinates? A selection set of Point entities? A series of User-selected locations? Another text file? Something else?
Cadastrophe1911 wrote:a list of point locations that do not include a z dim. each point will be a work point or WPT. The points will also be named as in WPT 1. I need the Lisp to count the points and give them each a corrisponding number. They have to be seperatied by tabs also. I would like to be able to enter a drawing and put points in the hole locations i need selected, then be able to export those point locations in the above format.
Partial solution:
Given a list that looks like this:
(setq ptlist '((0 0) (1 1) (2 2)))
this seems to have the desired result in the format of the external text file:
(setq
ptfile (open "C:/TEMP/PTFILE.TXT" "W")
inc 0
)
(write-line "Units\tInch" ptfile)
(foreach x ptlist
(write-line
(strcat "WPT\t" (itoa (setq inc (1+ inc))) "\t" (itoa (car x)) "\t" (itoa (last x)))
ptfile
)
)
(close ptfile)
That's assuming the X & Y values are all integers as in your original sample, but (rtos) could be used instead of (itoa) if they need to be real numbers.
Are you talking about putting Point entities in the hole locations, or Blocks, or something else?
Re: Help with exporting point locations to text file
Cadastrophe1911 wrote:Yes, I want to be able to put a point in a circle and have it list the point locations in that format. I can either copy it to a text file or have it put in a text file or cvs file
Minimally tested, but this seems to do that:
(setq
ptfile (open "C:/TEMP/PTFILE.TXT" "w"); <---- edit file path & name
inc 0
ptlist
(mapcar
'(lambda (x) (cdr (assoc 10 (entget x)))); Point locations
(mapcar 'cadr (ssnamex (ssget "_X" '((0 . "POINT"))))); all Point entities in drawing
); mapcar & ptlist
); setq
(write-line "Units\tInch" ptfile)
(foreach x ptlist
(write-line
(strcat
"WPT\t"
(itoa (setq inc (1+ inc))) "\t"
(rtos (car x) 2 2) "\t" ; X coordinate <--- edit precision, or use (itoa) instead
(rtos (cadr x) 2 2); Y coordinate <--- edit precision, or use (itoa) instead
); strcat
ptfile
)
)
(close ptfile)
With this result from a group of Point entities I placed in a drawing [tab-delimited in the .txt file, even though it doesn't come through that way in pasting it in here]:
Units Inch
WPT 1 -0.33 0.12
WPT 2 -0.01 0.27
WPT 3 0.36 0.07
WPT 4 0.30 -0.24
WPT 5 -0.24 -0.23
EDIT: If the only Circles in the drawing are ones you want to put Points in, and if you want to put Points in all Circles in the drawing, you could do the same without the middle-men of the Point entities, if you don't also need them for some other reason. Just replace "POINT" above with "CIRCLE" -- a Circle's center is the same (assoc 10) designation as a Point's location.
Cadastrophe1911 wrote:Tried to load it and got this
Command: _appload drill20.LSP successfully loaded.
Command: ; error: bad argument type: lselsetp nil....
That looks as though it found no Points. They would need to be actual Point entities [drawn with the Point command, or perhaps Measure or Divide], not Blocks or something. Or Circle entities if you switched to that. If they're actually Blocks or some other kind of thing, the (ssget) filter list would need to be different.
The .lsp file should contain something like:
(defun C:drill20 (/ ptfile inc ptlist); <--- or whatever command name
(setq
....the stuff in between from above....
(close ptfile)
); end defun
[And it can have other stuff, like a (princ) line just before the end.]
If you post the .lsp file itself as an attachment, someone can check whether the "wrapper" aspects surrounding the code I posted are correct. If the error message you posted occurs simply upon loading it, as it appears from what you posted, without typing in a command name, then there could be something about it that's triggering, for instance, the recall of the previous command, and that might be where the error is.
