Community
Here's the way I came up with to do that, a few years back. You can pick as many Polylines of any type(s) as you want in one running of the command and it will do it to all of them, it saves and restores System Variables for you, it works in different UCS's, and it does it in a way that doesn't need to figure out which type each one is nor pre-determine a count of how many places to Break each one. If you use AutoCAD 2015+, change the (command function name in the *error* handler near the top to (command-s .
Spoiler
;; PolylineSubDivide.lsp [command name: PSD]
;; SubDivide Polylines into separate Polylines of individual
;; line and arc segments, maintaining the original width(s) of
;; each segment, if any. Works on Lightweight 2D Polylines,
;; "heavy" 2D Polylines, and 3D Polylines.
;; Kent Cooper, April 2010
(defun C:PSD (/ *error* cmde osm blipm plset pl)
(defun *error* (errmsg)
(if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
(princ (strcat "\nError: " errmsg))
); end if
(setvar 'osmode osm)
(setvar 'blipmode blipm)
(command "_.undo" "_end")
(setvar 'cmdecho cmde)
); end defun - *error*
(setq cmde (getvar 'cmdecho))
(setvar 'cmdecho 0)
(command "_.undo" "_begin")
(setq osm (getvar 'osmode))
(setvar 'osmode 0)
(setq blipm (getvar 'blipmode))
(setvar 'blipmode 0)
(prompt "\nTo SubDivide Polylines,")
(setq plset (ssget '((0 . "*POLYLINE"))))
(if plset
(repeat (sslength plset)
(setq pl (ssname plset 0))
(if (> (vlax-curve-getEndParam pl) 1)
(progn ; then - more than 1 segment
(command
"_.break"
pl
(trans (vlax-curve-getPointAtParam pl 1) 0 1)
"@"
); end command
(while (> (vlax-curve-getEndParam (entlast)) 1)
(command
"_.break"
(entlast)
(trans (vlax-curve-getPointAtParam (entlast) 1) 0 1)
"@"
); end command
); end while
); end progn
); end if
(ssdel pl plset)
); end repeat
); end if
(setvar 'osmode osm)
(setvar 'blipmode blipm)
(command "_.undo" "_end")
(setvar 'cmdecho cmde)
(princ)
); end defun
(prompt "\nType PSD to SubDivide Polylines into separate segments.")
;; SubDivide Polylines into separate Polylines of individual
;; line and arc segments, maintaining the original width(s) of
;; each segment, if any. Works on Lightweight 2D Polylines,
;; "heavy" 2D Polylines, and 3D Polylines.
;; Kent Cooper, April 2010
(defun C:PSD (/ *error* cmde osm blipm plset pl)
(defun *error* (errmsg)
(if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
(princ (strcat "\nError: " errmsg))
); end if
(setvar 'osmode osm)
(setvar 'blipmode blipm)
(command "_.undo" "_end")
(setvar 'cmdecho cmde)
); end defun - *error*
(setq cmde (getvar 'cmdecho))
(setvar 'cmdecho 0)
(command "_.undo" "_begin")
(setq osm (getvar 'osmode))
(setvar 'osmode 0)
(setq blipm (getvar 'blipmode))
(setvar 'blipmode 0)
(prompt "\nTo SubDivide Polylines,")
(setq plset (ssget '((0 . "*POLYLINE"))))
(if plset
(repeat (sslength plset)
(setq pl (ssname plset 0))
(if (> (vlax-curve-getEndParam pl) 1)
(progn ; then - more than 1 segment
(command
"_.break"
pl
(trans (vlax-curve-getPointAtParam pl 1) 0 1)
"@"
); end command
(while (> (vlax-curve-getEndParam (entlast)) 1)
(command
"_.break"
(entlast)
(trans (vlax-curve-getPointAtParam (entlast) 1) 0 1)
"@"
); end command
); end while
); end progn
); end if
(ssdel pl plset)
); end repeat
); end if
(setvar 'osmode osm)
(setvar 'blipmode blipm)
(command "_.undo" "_end")
(setvar 'cmdecho cmde)
(princ)
); end defun
(prompt "\nType PSD to SubDivide Polylines into separate segments.")
Kent Cooper, AIA 
@BillZ wrote:
You would be beter off just exploding the pline, setting a selection set of the "Previous" and then looping through the entities and making them back into polylines with width and so on. ....
..
[I know this is Replying to a very old Post, but for future generations....]
That may be relatively easy if the Polyline you started with has a constant width. But it would be impossible if the width varies. That's the main reason, in my opinion, that single-point-Breaking them at every vertex is the better way to go.
Kent Cooper, AIA
Not sure why this topic is zombified.
@Anonymous
If you use AutoCAD 2015+, change the (command function name in the *error* handler near the top to (command-s .
Hope you don't mind giving us more info of command-s,
i encountered an error i've never seen before that refers to vl.crx and more arx files when running programs on Autocad 14 using command-s on programs written for Autocad 2017, specifically (command-s "_Reverse" e). It took me a while to realize to whats going on.
pBe
@pbejse wrote:
....
Hope you don't mind giving us more info of command-s,
i encountered an error i've never seen before that refers to vl.crx and more arx files when running programs on Autocad 14 using command-s on programs written for Autocad 2017, specifically (command-s "_Reverse" e). It took me a while to realize to whats going on.
pBe
Here is Help [for 2016] on (command-s). Partway down it discusses differences from the (command) function. You can't use (command) inside an *error* handler [it's still perfectly acceptable elsewhere] in 2015+ unless you go through some other shenanigans to make it allowable. But too-early versions don't recognize (command-s) at all [there may be some overlap, perhaps a version or two in which (command-s) had been introduced but you could still use (command) in *error* handlers -- I'm not sure]. So since the main thing I've typically wanted to do with a command in an *error* handler is Undo End, I've taken to using (vl... methods for Undo begin and end, because they work in all versions, so the same code can be used anywhere, without making separate files for older and newer versions of AutoCAD.
Kent Cooper, AIA
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
