Community
@cjacobi wrote:....
I am writing a routine that will place a piece of text at a specified point along a polyline. My problem is to determine the angle for the text. It needs to be the same as the segment of the polyline that it falls on. ....
The way I've done that kind of thing is to take the first derivative of the Polyline at the selected point, which will give you a virtual point location at that angle relative to 0,0,0. Try incorporating elements of this however they need to fit into whatever code you already have going:
(vl-load-com); just in case
(setq
esel (entsel "\nSelect Polyline: ")
pol (car esel); the Polyline's entity name
pt (osnap (cadr esel) "nea"); use Osnap to ensure it's really ON the Polyline
ang
(angle
'(0 0 0)
(vlax-curve-getFirstDeriv
pol
(vlax-curve-getParamAtPoint pol pt)
); end 1st deriv
); end angle & ang
); end setq
That will leave you with the angle stored in the 'ang' variable in radians, so you can use it directly that way if you're adding the Text using (entmake), or you would need to convert it with (angtos) to answer the rotation prompt in a Text command.
It can also be done by looking for the adjacent vertices, which is easier to do with Parameter values than with the coordinates from the entity data, something like this:
(setq
esel (entsel "\nSelect Polyline: ")
pol (car esel); the Polyline's entity name
pt (osnap (cadr esel) "nea"); use Osnap to ensure it's really ON the Polyline
par (fix (vlax-curve-getParamAtPoint pol pt)); the parameter value of the prior [upstream] vertex
ang
(angle
(vlax-curve-getPointAtParam pol par); location of upstream vertex
(vlax-curve-getPointAtParam pol (1+ par)); location of downstream vertex
); end angle & ang
); end setq
That's shorter than the first suggestion, but the first suggestion has the advantage [where applicable] that it will give the correct result even on Polyline arc segments, whereas the second suggestion will only work as you expect on line segments [unless you happen to pick an arc segment exactly at its midpoint].
Kent Cooper, AIA 
@cjacobi wrote:that's awesome Kent, thanks so much. Will try and work this into my code and hopefully get my command functioning the way I need to.
I do need to concider there may be arcs invovled, so thanks again for providing two options.
....
You're welcome. You could also use the same [presumably with a change in the selection prompt] on any object in the "vlax-curve" class [which doesn't necessarily mean it has to be "curved" by the generic definition] -- Line, Arc, Circle, Ellipse, Spline, Xline, Ray, Leader, maybe a couple of other things.
Kent Cooper, AIA
@stevor wrote:
May want to test the generated slope value at the ends of the polylines, as they may not be what you expect.
True, though only if selected precisely at the very end. Given what they are looking to do, that doesn't seem very likely, but it's something to be aware of.
Kent Cooper, AIA
Another approach would be to id the line segment of the polyline having an endpoint nearest the point(pt1) with which the polyline is selected and thereafter finding the slope of the line segment using the endpoints(pt2, pt3). I have been away from lisp a number of years so it would be something if I could even stab at the code. Would someone get me started? Loop through the line segments. Minimize "d".
@btlsp2014 wrote:
Another approach would be to id the line segment of the polyline having an endpoint nearest the point(pt1) with which the polyline is selected and thereafter finding the slope of the line segment using the endpoints(pt2, pt3). .....
That's what the second routine in my message with two routines in it does. [I'd specify a Message number, but for the time being those are not showing -- I hope they'll come back soon.]
Kent Cooper, AIA
![Autodesk Design & Make Report](https://forums.autodesk.com/t5/image/serverpage/image-id/1350519iCB55845EBFC43016/image-size/large?v=v2&px=999" "Autodesk Design & Make Report")
