Fast Open (Skip All)

[KentKeller]

Is there any way to set Fast Open as the default?  I am having to open hundreds of files and do nothing more than take a quick look at them and then print them.  Each file I have to make sure it is clicked on in the open dialog (I can't paste in the filename) and then open options and check Fast Open.   Am I missing the setting in App Options somewhere, or is there a registry hack to change it?

Thanks

[admaiora]

I don't think it is possible.

But i leave the last word to who know it for sure.

[ruthsteed · Accepted solution]

Sorry, but unfortunately the setting you want doesn't exist.  It's an interesting idea, though.  Would a sticky option in the options dialog itself fit your purpose?  This would just save the setting until you changed it or exited Inventor.  I think it would be easier to find and use than an application option.

In the meantime, though, here is a bit of VBA code that might help.  Paste this VBA code into a module in your default project, then use the Customize command (Tools>Customize) to add a button to the environments you'd want it in (Choose "Macros" in the "Choose commands from" dropdown, then select "FastOpenDrawingCmd" and  add it to one or more tabs).  I'd recommend the "Zero Document|Get Started" and "Drawing|Place Views" since these are the default tabs when no documents are open or when a drawing is opened, but you can add as many (or few) as suit your purposes.  The button added will bring up a file dialog for selecting drawings to open.  Any Inventor drawings selected this way (including multiple selections) will be opened using "Fast Open".

'>>> Snip VBA here 

Sub FastOpenDrawingCmd()
    Dim oDlg As FileDialog
    Dim bExpress As Boolean
    ThisApplication.CreateFileDialog oDlg
    oDlg.DialogTitle = "Open Drawings Using FastOpen"
    oDlg.filter = "Inventor Drawings (*.idw)|*.idw"
    oDlg.MultiSelectEnabled = True
    oDlg.ShowOpen
    If oDlg.filename <> "" Then
        Dim filename As String: filename = oDlg.filename
        Dim options As NameValueMap
        Set options = ThisApplication.TransientObjects.CreateNameValueMap
        options.Add "FastOpen", True
        Dim pipe As Integer
        Dim strFile As String
        Do
            pipe = InStr(1, filename, "|")
            If pipe > 0 Then
            strFile = Left(filename, pipe - 1)
                filename = Right(filename, Len(filename) - pipe)
            Else
                strFile = filename
            End If
            ThisApplication.Documents.OpenWithOptions strFile, options
        Loop While pipe > 0
    End If
End Sub

'>>> Snip here

Hope this helps,

Ruth Steed

Inventor Development

[KentKeller]

Thanks Ruth,

Yes a sticky option would work fine, but it seems like it should stay sticky all the time just like Skip all unresolved files does.

Thanks