Label Assemblies (by CGS plus from Exchange store) update for 2014?

[neilyj666]

I installed this great little app for 2013 and it works well but it doesn't install for 2014. I have emailed the author but had no response.

All the relevant cuix/dll files etc etc are in my Roaming folder and I NETLOADED the dll and it sort of worked but not as slickly as in  2013.

Any idea how to implement this in 2014 (in the event CGS plus do not reply)

Thanks

[gregor.pipan]

Hi,

Just signed int to this forum and will try to answer this post although it's a bit old. Hope it finds you.

We really have not ported this tool to support 2014 and 2015 versions of AutoCAD Civil 3D on Exchange Store. It is not that we don't want to do it, it is just that we are involved in so many large infrastructure software development projects that our programers don't get to it.

But we have only recently published new collection of CGS Civil 3D Tools 2015 which brings lots of new features to Civil 3D users.

I hope you will find it usefull although it is not a free collection. But check the pricing! A guarantee you is more than convenient 

Gregor Pipan

CGS plus, EUROPE Head-Office

[neilyj666]

This is a bit disappointing; back to using mtext then

[~Opie · Accepted solution]

Here is a VLisp routine to do something similar.  It isn't as polished, but it does what I need it to.  You will need to set your desired text style and layer beforehand.

(defun c:LabelAssembly (/	      Entity	    Name
			Position      TextInsertion Object
			_Space	      _GetObjectID  _GetFieldString
		       )
  (vl-load-com)
  (defun _Space	(/ *DOC* space)
    ;;_ Returns the active space object
    (setq *DOC* (vla-get-activedocument (vlax-get-acad-object)))
    (setq space	(if (= 1 (vla-get-activespace *DOC*))
		  (vla-get-modelspace *DOC*) ;_ Model Space
		  (if (= (vla-get-mspace *DOC*) :vlax-true)
		    (vla-get-modelspace *DOC*) ;_ Model Space through Viewport
		    (vla-get-paperspace *DOC*) ;_ Paper Space
		  )
		)
    )
  )
  (defun _GetObjectID (o / util oid)
    ;;_ Returns Object ID as string
    (if	(> (strlen (vl-prin1-to-string (vlax-get-acad-object))) 40)
      (progn ;_ Is 64 bit
	(setq util (vla-get-utility
		     (vla-get-activedocument (vlax-get-acad-object))
		   )
	      oID  (vlax-invoke-method
		     util
		     "GetObjectIdString"
		     o
		     :vlax-False
		   )
	)
      )
      (progn ;_ Is 32 bit
	(setq oID (vla-get-objectid o))
      )
    )
  )
  (defun _GetFieldString (oid property /)
    ;;_ Requires an objectid and valid property name in string format
    ;;_ No validation is attempted
    (strcat "\%<\\AcObjProp Object(\%<\\_ObjId "
	    oid				">\%)."
	    property			" \\f \"\%tc1\">\%"
	   )
  )
  (setq Entity (ssget ":S" '((0 . "AECC_ASSEMBLY"))))
  (if Entity
    (progn
      (setq
	Object	      (vlax-ename->vla-object (ssname Entity 0))
	Position      (vla-get-position Object)
	TextInsertion (vlax-3d-point
			(mapcar	'+
				(list (vlax-get-property Position 'X)
				      (vlax-get-property Position 'Y)
				      (vlax-get-property Position 'Z)
				)
				'(5.0 -10.0 0.0) ;_ Text offset from assembly insertion point
			)
		      )
      )
      (vla-addtext
	(_space)
	(_GetFieldString (_GetObjectID Object) "Name")
	TextInsertion
	4.8 ;_ Text height
      )
      (princ (strcat "Labeled: " (chr 34) (vla-get-name object) (chr 34)))
    )
  )
  (princ)
)

 Let me know if it is missing any helper routines.  I think they are all included.

[neilyj666]

Many thanks for this, I'll try it out in the next day or so and let you know the outcome

[~Opie]

Does the routine work for you?

[neilyj666]

Forgot to respond - yes it works just great

[~Opie]

Good. Just wanted to make sure it worked as intended.